VB.NET Convert.ChangeType方法代码示例

OStack程序员社区-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.Convert.ChangeType方法的典型用法代码示例。如果您正苦于以下问题：VB.NET Convert.ChangeType方法的具体用法？VB.NET Convert.ChangeType怎么用？VB.NET Convert.ChangeType使用的例子？那么恭喜您, 这里精选的方法代码示例或许可以为您提供帮助。您也可以进一步了解该方法所在类System.Convert的用法示例。

在下文中一共展示了Convert.ChangeType方法的8个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: ChangeTypeTest

Public Class ChangeTypeTest
    
    Public Shared Sub Main()
        Dim d As [Double] = - 2.345
        Dim i As Integer = CInt(Convert.ChangeType(d, GetType(Integer)))
        
        Console.WriteLine("The double value {0} when converted to an int becomes {1}", d, i)
        Dim s As String = "12/12/98"
        Dim dt As DateTime = CType(Convert.ChangeType(s, GetType(DateTime)), DateTime)
        
        Console.WriteLine("The string value {0} when converted to a Date becomes {1}", s, dt)
    End Sub
End Class

开发者ID:VB.NET开发者，项目名称:System，代码行数:13，代码来源:Convert.ChangeType

示例2: Example

Public Enum Continent As Integer
   Africa = 0
   Antarctica = 1
   Asia = 2
   Australia = 3
   Europe = 4
   NorthAmerica = 5
   SouthAmerica = 6
End Enum

Module Example
   Public Sub Main()
      ' Convert a Continent to a Double.
      Dim cont As Continent = Continent.NorthAmerica
      Console.WriteLine("{0:N2}", 
                        Convert.ChangeType(cont, GetType(Double)))
   
      ' Convert a Double to a Continent.
      Dim number As Double = 6.0
      Try
         Console.WriteLine("{0}", 
                           Convert.ChangeType(number, GetType(Continent)))
      Catch e As InvalidCastException
         Console.WriteLine("Cannot convert a Double to a Continent")
      End Try
      
      Console.WriteLine("{0}", CType(number, Continent))   
   End Sub
End Module

开发者ID:VB.NET开发者，项目名称:System，代码行数:29，代码来源:Convert.ChangeType

输出：

5.00
Cannot convert a Double to a Continent
SouthAmerica

示例3: Example

Module Example
   Public Sub Main()
      Dim intValue1 As Integer? = 12893
      Dim dValue1 As Double = CType(Convert.ChangeType(intValue1, GetType(Double)), Double)
      Console.WriteLine("{0} ({1})--> {2} ({3})", intValue1, intValue1.GetType().Name,
                        dValue1, dValue1.GetType().Name)
      

      Dim fValue1 As Single = 16.3478
      Dim intValue2 As Integer? = CType(fValue1, Integer) 
      Console.WriteLine("{0} ({1})--> {2} ({3})", fValue1, fValue1.GetType().Name,
                        intValue2, intValue2.GetType().Name)
   End Sub
End Module

开发者ID:VB.NET开发者，项目名称:System，代码行数:14，代码来源:Convert.ChangeType

输出：

12893 (Int32)--> 12893 (Double)
16.3478 (Single)--> 16 (Int32)

示例4: ChangeTypeTest

Public Class ChangeTypeTest
    
    Public Shared Sub Main()
        Dim d As [Double] = - 2.345
        Dim i As Integer = CInt(Convert.ChangeType(d, TypeCode.Int32))
        
        Console.WriteLine("The Double {0} when converted to an Int32 is {1}", d, i)
        Dim s As String = "12/12/2009"
        Dim dt As DateTime = CDate(Convert.ChangeType(s, TypeCode.DateTime))
        
        Console.WriteLine("The String {0} when converted to a Date is {1}", s, dt)
    End Sub 
End Class

开发者ID:VB.NET开发者，项目名称:System，代码行数:13，代码来源:Convert.ChangeType

输出：

The Double -2.345 when converted to an Int32 is -2
The String 12/12/2009 when converted to a Date is 12/12/2009 12:00:00 AM

示例5: New

' 导入命名空间
Imports System.Globalization

Public Class Temperature : Implements IConvertible
   Private m_Temp As Decimal

   Public Sub New(temperature As Decimal)
      Me.m_Temp = temperature
   End Sub
   
   Public ReadOnly Property Celsius() As Decimal
      Get
         Return Me.m_Temp
      End Get   
   End Property
   
   Public ReadOnly Property Kelvin() As Decimal
      Get
         Return Me.m_Temp + 273.15d   
      End Get
   End Property
   
   Public ReadOnly Property Fahrenheit() As Decimal
      Get
         Return Math.Round(CDec(Me.m_Temp * 9 / 5 + 32), 2)
      End Get      
   End Property
   
   Public Overrides Function ToString() As String
      Return m_Temp.ToString("N2") & "°C"
   End Function

   ' IConvertible implementations.
   Public Function GetTypeCode() As TypeCode _
                   Implements IConvertible.GetTypeCode
      Return TypeCode.Object
   End Function
   
   Public Function ToBoolean(provider As IFormatProvider) As Boolean _
                   Implements IConvertible.ToBoolean
      If m_Temp = 0 Then
         Return False
      Else
         Return True
      End If
   End Function 
   
   Public Function ToByte(provider As IFormatProvider) As Byte _
                   Implements IConvertible.ToByte
      If m_Temp < Byte.MinValue Or m_Temp > Byte.MaxValue Then
         Throw New OverflowException(String.Format("{0} is out of range of the Byte type.", _ 
                                                   Me.m_Temp)) 
      Else
         Return Decimal.ToByte(Me.m_Temp)
      End If       
   End Function
   
   Public Function ToChar(provider As IFormatProvider) As Char _
                   Implements IConvertible.ToChar
      Throw New InvalidCastException("Temperature to Char conversion is not supported.")
   End Function 
   
   Public Function ToDateTime(provider As IFormatProvider) As Date _
                   Implements IConvertible.ToDateTime
      Throw New InvalidCastException("Temperature to DateTime conversion is not supported.")
   End Function
   
   Public Function ToDecimal(provider As IFormatProvider) As Decimal _
                   Implements IConvertible.ToDecimal
      Return Me.m_Temp
   End Function
   
   Public Function ToDouble(provider As IFormatProvider) As Double _
                   Implements IConvertible.ToDouble
      Return Decimal.ToDouble(Me.m_Temp)
   End Function   
   
   Public Function ToInt16(provider As IFormatProvider) As Int16 _
                   Implements IConvertible.ToInt16
      If Me.m_Temp < Int16.MinValue Or Me.m_Temp > Int16.MaxValue Then
         Throw New OverflowException(String.Format("{0} is out of range of the Int16 type.", _
                                                   Me.m_Temp))
      Else
         Return Decimal.ToInt16(Me.m_Temp)   
      End If
   End Function
   
   Public Function ToInt32(provider As IFormatProvider) As Int32 _
                   Implements IConvertible.ToInt32
      If Me.m_Temp < Int32.MinValue Or Me.m_Temp > Int32.MaxValue Then
         Throw New OverflowException(String.Format("{0} is out of range of the Int32 type.", _
                                                   Me.m_Temp))
      Else
         Return Decimal.ToInt32(Me.m_Temp)
      End If      
   End Function
   
   Public Function ToInt64(provider As IFormatProvider) As Int64 _
                   Implements IConvertible.ToInt64
      If Me.m_Temp < Int64.MinValue Or Me.m_Temp > Int64.MaxValue Then
         Throw New OverflowException(String.Format("{0} is out of range of the Int64 type.", _
                                                   Me.m_Temp))
      Else
         Return Decimal.ToInt64(Me.m_Temp)
      End If      
   End Function
   
   Public Function ToSByte(provider As IFormatProvider) As SByte _
                   Implements IConvertible.ToSByte
      If Me.m_Temp < SByte.MinValue Or Me.m_Temp > SByte.MaxValue Then
         Throw New OverflowException(String.Format("{0} is out of range of the SByte type.", _
                                                   Me.m_Temp))
      Else
         Return Decimal.ToSByte(Me.m_Temp)
      End If      
   End Function

   Public Function ToSingle(provider As IFormatProvider) As Single _
                   Implements IConvertible.ToSingle
      Return Decimal.ToSingle(Me.m_Temp)
   End Function

   Public Overloads Function ToString(provider As IFormatProvider) As String _
                   Implements IConvertible.ToString
      Return m_Temp.ToString("N2", provider) & "°C"
   End Function
   
   Public Function ToType(conversionType As Type, provider As IFormatProvider) As Object _
                   Implements IConvertible.ToType
      Select Case Type.GetTypeCode(conversionType)
         Case TypeCode.Boolean 
            Return Me.ToBoolean(Nothing)
         Case TypeCode.Byte
            Return Me.ToByte(Nothing)
         Case TypeCode.Char
            Return Me.ToChar(Nothing)
         Case TypeCode.DateTime
            Return Me.ToDateTime(Nothing)
         Case TypeCode.Decimal
            Return Me.ToDecimal(Nothing)
         Case TypeCode.Double
            Return Me.ToDouble(Nothing)
         Case TypeCode.Int16
            Return Me.ToInt16(Nothing)
         Case TypeCode.Int32
            Return Me.ToInt32(Nothing)
         Case TypeCode.Int64
            Return Me.ToInt64(Nothing)
         Case TypeCode.Object
            If GetType(Temperature).Equals(conversionType) Then
               Return Me
            Else
               Throw New InvalidCastException(String.Format("Conversion to a {0} is not supported.", _
                                                            conversionType.Name))
            End If 
         Case TypeCode.SByte
            Return Me.ToSByte(Nothing)
         Case TypeCode.Single
            Return Me.ToSingle(Nothing)
         Case TypeCode.String
            Return Me.ToString(provider)
         Case TypeCode.UInt16
            Return Me.ToUInt16(Nothing)
         Case TypeCode.UInt32
            Return Me.ToUInt32(Nothing)
         Case TypeCode.UInt64
            Return Me.ToUInt64(Nothing)   
         Case Else
            Throw New InvalidCastException(String.Format("Conversion to {0} is not supported.", conversionType.Name))   
      End Select
   End Function
   
   Public Function ToUInt16(provider As IFormatProvider) As UInt16 _
                   Implements IConvertible.ToUInt16
      If Me.m_Temp < UInt16.MinValue Or Me.m_Temp > UInt16.MaxValue Then
         Throw New OverflowException(String.Format("{0} is out of range of the UInt16 type.", _
                                                   Me.m_Temp))
      Else
         Return Decimal.ToUInt16(Me.m_Temp)
      End If   
   End Function

   Public Function ToUInt32(provider As IFormatProvider) As UInt32 _
                   Implements IConvertible.ToUInt32
      If Me.m_Temp < UInt32.MinValue Or Me.m_Temp > UInt32.MaxValue Then
         Throw New OverflowException(String.Format("{0} is out of range of the UInt32 type.", _
                                                   Me.m_Temp))
      Else
         Return Decimal.ToUInt32(Me.m_Temp)
      End If   
   End Function
   
   Public Function ToUInt64(provider As IFormatProvider) As UInt64 _
                   Implements IConvertible.ToUInt64
      If Me.m_Temp < UInt64.MinValue Or Me.m_Temp > UInt64.MaxValue Then
         Throw New OverflowException(String.Format("{0} is out of range of the UInt64 type.", _
                                                   Me.m_Temp))
      Else
         Return Decimal.ToUInt64(Me.m_temp)
      End If   
   End Function
End Class

开发者ID:VB.NET开发者，项目名称:System，代码行数:202，代码来源:Convert.ChangeType

示例6: Example

Module Example
   Public Sub Main()
      Dim cool As New Temperature(5)
      Dim targetTypes() As Type = { GetType(SByte), GetType(Int16), GetType(Int32), _
                                    GetType(Int64), GetType(Byte), GetType(UInt16), _
                                    GetType(UInt32), GetType(UInt64), GetType(Decimal), _
                                    GetType(Single), GetType(Double), GetType(String) }
      Dim provider As New CultureInfo("fr-FR")
      
      For Each targetType As Type In targetTypes
         Try
            Dim value As Object = Convert.ChangeType(cool, targetType, provider)
            Console.WriteLine("Converted {0} {1} to {2} {3}.", _
                              cool.GetType().Name, cool.ToString(), _
                              targetType.Name, value)
         Catch e As InvalidCastException
            Console.WriteLine("Unsupported {0} --> {1} conversion.", _
                              cool.GetType().Name, targetType.Name)
         Catch e As OverflowException
            Console.WriteLine("{0} is out of range of the {1} type.", _
                              cool, targetType.Name)
         End Try                     
      Next
   End Sub
End Module

开发者ID:VB.NET开发者，项目名称:System，代码行数:25，代码来源:Convert.ChangeType

输出：

Converted Temperature 5.00°C to SByte 5.
Converted Temperature 5.00°C to Int16 5.
Converted Temperature 5.00°C to Int32 5.
Converted Temperature 5.00°C to Int64 5.
Converted Temperature 5.00°C to Byte 5.
Converted Temperature 5.00°C to UInt16 5.
Converted Temperature 5.00°C to UInt32 5.
Converted Temperature 5.00°C to UInt64 5.
Converted Temperature 5.00°C to Decimal 5.
Converted Temperature 5.00°C to Single 5.
Converted Temperature 5.00°C to Double 5.
Converted Temperature 5.00°C to String 5,00°C.

示例7: Example

Module Example
   Public Sub Main()
      Dim intValue1 As Integer? = 12893
      Dim dValue1 As Double = CType(Convert.ChangeType(intValue1, GetType(Double), Nothing), Double)
      Console.WriteLine("{0} ({1})--> {2} ({3})", intValue1, intValue1.GetType().Name,
                        dValue1, dValue1.GetType().Name)
      

      Dim fValue1 As Single = 16.3478
      Dim intValue2 As Integer? = CType(fValue1, Integer) 
      Console.WriteLine("{0} ({1})--> {2} ({3})", fValue1, fValue1.GetType().Name,
                        intValue2, intValue2.GetType().Name)
   End Sub
End Module

开发者ID:VB.NET开发者，项目名称:System，代码行数:14，代码来源:Convert.ChangeType

输出：

12893 (Int32)--> 12893 (Double)
16.3478 (Single)--> 16 (Int32)

示例8: Example

' 导入命名空间
Imports System.Globalization

Public Class InterceptProvider : Implements IFormatProvider
   Public Function GetFormat(formatType As Type) As Object _
          Implements IFormatProvider.GetFormat
      If formatType.Equals(GetType(NumberFormatInfo)) Then
         Console.WriteLine("   Returning a fr-FR numeric format provider.")
         Return New CultureInfo("fr-FR").NumberFormat
      ElseIf formatType.Equals(GetType(DateTimeFormatInfo)) Then
         Console.WriteLine("   Returning an en-US date/time format provider.")
         Return New CultureInfo("en-US").DateTimeFormat
      Else
         Console.WriteLine("   Requesting a format provider of {0}.", formatType.Name)
         Return Nothing
      End If
   End Function
End Class

Module Example
   Public Sub Main()
      Dim values() As Object = { 103.5r, #12/26/2010 2:34PM# }
      Dim provider As New InterceptProvider()
      
      ' Convert value to each of the types represented in TypeCode enum.
      For Each value As Object In values
         ' Iterate types in TypeCode enum.
         For Each enumType As TypeCode In DirectCast([Enum].GetValues(GetType(TypeCode)), TypeCode())         
            If enumType = TypeCode.DbNull Or enumType = TypeCode.Empty Then Continue For
            
            Try
               Console.WriteLine("{0} ({1}) --> {2} ({3}).", _
                                 value, value.GetType().Name, _
                                 Convert.ChangeType(value, enumType, provider), _
                                 enumType.ToString())
            Catch e As InvalidCastException
               Console.WriteLine("Cannot convert a {0} to a {1}", _
                                 value.GetType().Name, enumType.ToString())
            Catch e As OverflowException
               Console.WriteLine("Overflow: {0} is out of the range of a {1}", _
                                 value, enumType.ToString())
            End Try
         Next
         Console.WriteLine()
      Next
   End Sub
End Module

开发者ID:VB.NET开发者，项目名称:System，代码行数:47，代码来源:Convert.ChangeType

输出：

103.5 (Double) --> 103.5 (Object).
103.5 (Double) --> True (Boolean).
Cannot convert a Double to a Char
103.5 (Double) --> 104 (SByte).
103.5 (Double) --> 104 (Byte).
103.5 (Double) --> 104 (Int16).
103.5 (Double) --> 104 (UInt16).
103.5 (Double) --> 104 (Int32).
103.5 (Double) --> 104 (UInt32).
103.5 (Double) --> 104 (Int64).
103.5 (Double) --> 104 (UInt64).
103.5 (Double) --> 103.5 (Single).
103.5 (Double) --> 103.5 (Double).
103.5 (Double) --> 103.5 (Decimal).
Cannot convert a Double to a DateTime
Returning a fr-FR numeric format provider.
103.5 (Double) --> 103,5 (String).

12/26/2010 2:34:00 PM (DateTime) --> 12/26/2010 2:34:00 PM (Object).
Cannot convert a DateTime to a Boolean
Cannot convert a DateTime to a Char
Cannot convert a DateTime to a SByte
Cannot convert a DateTime to a Byte
Cannot convert a DateTime to a Int16
Cannot convert a DateTime to a UInt16
Cannot convert a DateTime to a Int32
Cannot convert a DateTime to a UInt32
Cannot convert a DateTime to a Int64
Cannot convert a DateTime to a UInt64
Cannot convert a DateTime to a Single
Cannot convert a DateTime to a Double
Cannot convert a DateTime to a Decimal
12/26/2010 2:34:00 PM (DateTime) --> 12/26/2010 2:34:00 PM (DateTime).
Returning an en-US date/time format provider.
12/26/2010 2:34:00 PM (DateTime) --> 12/26/2010 2:34:00 PM (String).

注：本文中的System.Convert.ChangeType方法示例整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。