VB.NET IResourceProvider接口代码示例

OStack程序员社区-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.Web.Compilation.IResourceProvider接口的典型用法代码示例。如果您正苦于以下问题：VB.NET IResourceProvider接口的具体用法？VB.NET IResourceProvider怎么用？VB.NET IResourceProvider使用的例子？那么恭喜您, 这里精选的接口代码示例或许可以为您提供帮助。

在下文中一共展示了IResourceProvider接口的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: CustomResourceProviderFactory

<DesignTimeResourceProviderFactoryAttribute(GetType(CustomDesignTimeResourceProviderFactory))> _
Public Class CustomResourceProviderFactory
    Inherits ResourceProviderFactory
    Public Overrides Function CreateGlobalResourceProvider(ByVal classname As String) As IResourceProvider
        Return New CustomResourceProvider(Nothing, classname)
    End Function
    Public Overrides Function CreateLocalResourceProvider(ByVal virtualPath As String) As IResourceProvider
        Return New CustomResourceProvider(virtualPath, Nothing)
    End Function
End Class

' Define the resource provider for global and local resources.
Friend Class CustomResourceProvider
    Implements IResourceProvider
    Dim _virtualPath As String
    Dim _className As String

    Public Sub New(ByVal virtualPath As String, ByVal classname As String)
        _virtualPath = virtualPath
        _className = classname
    End Sub

    Private Function GetResourceCache(ByVal culturename As String) As IDictionary
        Return System.Web.HttpContext.Current.Cache(culturename)
    End Function

    Function GetObject(ByVal resourceKey As String, ByVal culture As CultureInfo) As Object Implements IResourceProvider.GetObject
        Dim value As Object
        Dim cultureName As String
        cultureName = Nothing
        If (IsNothing(culture)) Then
            cultureName = CultureInfo.CurrentUICulture.Name
        Else
            cultureName = culture.Name
        End If

        value = GetResourceCache(cultureName)(resourceKey)
        If (value = Nothing) Then
            value = GetResourceCache(Nothing)(resourceKey)
        End If
        Return value
    End Function


    ReadOnly Property ResourceReader() As IResourceReader Implements IResourceProvider.ResourceReader
        Get
            Dim cultureName As String
            Dim currentUICulture As CultureInfo
            cultureName = Nothing
            currentUICulture = CultureInfo.CurrentUICulture
            If (Not (String.Equals(currentUICulture.Name, CultureInfo.InstalledUICulture.Name))) Then
                cultureName = currentUICulture.Name
            End If

            Return New CustomResourceReader(GetResourceCache(cultureName))
        End Get
    End Property
End Class

Friend NotInheritable Class CustomResourceReader
    Implements IResourceReader
    Private _resources As IDictionary

    Public Sub New(ByVal resources As IDictionary)
        _resources = resources
    End Sub

    Function GetEnumerator1() As IDictionaryEnumerator Implements IResourceReader.GetEnumerator
        Return _resources.GetEnumerator()
    End Function

    Sub Close() Implements IResourceReader.Close

    End Sub

    Function GetEnumerator() As IEnumerator Implements IEnumerable.GetEnumerator
        Return _resources.GetEnumerator()
    End Function

    Sub Dispose() Implements IDisposable.Dispose

    End Sub
End Class

开发者ID:VB.NET开发者，项目名称:System.Web.Compilation，代码行数:83，代码来源:IResourceProvider

注：本文中的System.Web.Compilation.IResourceProvider接口示例整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。