VB.NET RSAPKCS1KeyExchangeFormatter类代码示例

OStack程序员社区-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.Security.Cryptography.RSAPKCS1KeyExchangeFormatter类的典型用法代码示例。如果您正苦于以下问题：VB.NET RSAPKCS1KeyExchangeFormatter类的具体用法？VB.NET RSAPKCS1KeyExchangeFormatter怎么用？VB.NET RSAPKCS1KeyExchangeFormatter使用的例子？那么恭喜您, 这里精选的类代码示例或许可以为您提供帮助。

在下文中一共展示了RSAPKCS1KeyExchangeFormatter类的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: Alice

' 导入命名空间
Imports System.IO
Imports System.Security.Cryptography
Imports System.Text




Class Alice

    Public Shared Sub Main(ByVal args() As String)
        Dim bob As New Bob()
        Try
            Dim rsaKey As New RSACryptoServiceProvider()
            Try
                ' Get Bob's public key
                rsaKey.ImportCspBlob(bob.key)
                Dim encryptedSessionKey As Byte() = Nothing
                Dim encryptedMessage As Byte() = Nothing
                Dim iv As Byte() = Nothing
                Send(rsaKey, "Secret message", iv, encryptedSessionKey, encryptedMessage)
                bob.Receive(iv, encryptedSessionKey, encryptedMessage)
            Finally
                rsaKey.Dispose()
            End Try
        Finally
            bob.Dispose()
        End Try

    End Sub


    Private Shared Sub Send(ByVal key As RSA, ByVal secretMessage As String, ByRef iv() As Byte, ByRef encryptedSessionKey() As Byte, ByRef encryptedMessage() As Byte)
        Dim aes = New AesCryptoServiceProvider()
        Try
            iv = aes.IV

            ' Encrypt the session key
            Dim keyFormatter As New RSAPKCS1KeyExchangeFormatter(key)
            encryptedSessionKey = keyFormatter.CreateKeyExchange(aes.Key, GetType(Aes))

            ' Encrypt the message
            Dim ciphertext As New MemoryStream()
            Try
                Dim cs As New CryptoStream(ciphertext, aes.CreateEncryptor(), CryptoStreamMode.Write)
                Try
                    Dim plaintextMessage As Byte() = Encoding.UTF8.GetBytes(secretMessage)
                    cs.Write(plaintextMessage, 0, plaintextMessage.Length)
                    cs.Close()

                    encryptedMessage = ciphertext.ToArray()
                Finally
                    cs.Dispose()
                End Try
            Finally
                ciphertext.Dispose()
            End Try
        Finally
            aes.Dispose()
        End Try

    End Sub
End Class

Public Class Bob
    Implements IDisposable
    Public key() As Byte
    Private rsaKey As New RSACryptoServiceProvider()

    Public Sub New()
        key = rsaKey.ExportCspBlob(False)

    End Sub

    Public Sub Receive(ByVal iv() As Byte, ByVal encryptedSessionKey() As Byte, ByVal encryptedMessage() As Byte)

        Dim aes = New AesCryptoServiceProvider()
        Try
            aes.IV = iv

            ' Decrypt the session key
            Dim keyDeformatter As New RSAPKCS1KeyExchangeDeformatter(rsaKey)
            aes.Key = keyDeformatter.DecryptKeyExchange(encryptedSessionKey)

            ' Decrypt the message
            Dim plaintext As New MemoryStream()
            Try
                Dim cs As New CryptoStream(plaintext, aes.CreateDecryptor(), CryptoStreamMode.Write)
                Try
                    cs.Write(encryptedMessage, 0, encryptedMessage.Length)
                    cs.Close()

                    Dim message As String = Encoding.UTF8.GetString(plaintext.ToArray())
                    Console.WriteLine(message)
                Finally
                    cs.Dispose()
                End Try
            Finally
                plaintext.Dispose()
            End Try
        Finally
            aes.Dispose()
        End Try

    End Sub
    Public Overloads Sub Dispose() Implements IDisposable.Dispose
        rsaKey.Dispose()
    End Sub
End Class

开发者ID:VB.NET开发者，项目名称:System.Security.Cryptography，代码行数:109，代码来源:RSAPKCS1KeyExchangeFormatter

注：本文中的System.Security.Cryptography.RSAPKCS1KeyExchangeFormatter类示例由纯净天空整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。