VB.NET RSAOAEPKeyExchangeFormatter类代码示例

OStack程序员社区-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.Security.Cryptography.RSAOAEPKeyExchangeFormatter类的典型用法代码示例。如果您正苦于以下问题：VB.NET RSAOAEPKeyExchangeFormatter类的具体用法？VB.NET RSAOAEPKeyExchangeFormatter怎么用？VB.NET RSAOAEPKeyExchangeFormatter使用的例子？那么恭喜您, 这里精选的类代码示例或许可以为您提供帮助。

在下文中一共展示了RSAOAEPKeyExchangeFormatter类的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: Alice

' 导入命名空间
Imports System.IO
Imports System.Security.Cryptography
Imports System.Text




Class Alice

    Public Shared Sub Main(ByVal args() As String)
        Using bob As New Bob()
            Using rsaKey As New RSACryptoServiceProvider()
                    ' Get Bob's public key
                    rsaKey.ImportCspBlob(bob.key)
                    Dim encryptedSessionKey As Byte() = Nothing
                    Dim encryptedMessage As Byte() = Nothing
                    Dim iv As Byte() = Nothing
                    Send(rsaKey, "Secret message", iv, encryptedSessionKey, encryptedMessage)
                    bob.Receive(iv, encryptedSessionKey, encryptedMessage)
            End Using
        End Using

    End Sub


    Private Shared Sub Send(ByVal key As RSA, ByVal secretMessage As String, ByRef iv() As Byte, ByRef encryptedSessionKey() As Byte, ByRef encryptedMessage() As Byte)
        Using aes = New AesCryptoServiceProvider()

            iv = aes.IV

            ' Encrypt the session key
            Dim keyFormatter As New RSAOAEPKeyExchangeFormatter(key)
            encryptedSessionKey = keyFormatter.CreateKeyExchange(aes.Key, GetType(Aes))

            ' Encrypt the message
            Using ciphertext As New MemoryStream()
                Using cs As New CryptoStream(ciphertext, aes.CreateEncryptor(), CryptoStreamMode.Write)
                    Dim plaintextMessage As Byte() = Encoding.UTF8.GetBytes(secretMessage)
                    cs.Write(plaintextMessage, 0, plaintextMessage.Length)
                    cs.Close()

                    encryptedMessage = ciphertext.ToArray()
                End Using
            End Using
        End Using

    End Sub
End Class

Public Class Bob
    Implements IDisposable
    Public key() As Byte
    Private rsaKey As New RSACryptoServiceProvider()

    Public Sub New()
        key = rsaKey.ExportCspBlob(False)

    End Sub

    Public Sub Receive(ByVal iv() As Byte, ByVal encryptedSessionKey() As Byte, ByVal encryptedMessage() As Byte)

        Using aes = New AesCryptoServiceProvider()

            aes.IV = iv

            ' Decrypt the session key
            Dim keyDeformatter As New RSAOAEPKeyExchangeDeformatter(rsaKey)
            aes.Key = keyDeformatter.DecryptKeyExchange(encryptedSessionKey)

            ' Decrypt the message
            Using plaintext As New MemoryStream()
                Using cs As New CryptoStream(plaintext, aes.CreateDecryptor(), CryptoStreamMode.Write)
                        cs.Write(encryptedMessage, 0, encryptedMessage.Length)
                        cs.Close()

                        Dim message As String = Encoding.UTF8.GetString(plaintext.ToArray())
                        Console.WriteLine(message)
                End Using
            End Using
        End Using

    End Sub
    Public Overloads Sub Dispose() Implements IDisposable.Dispose
        rsaKey.Dispose()
    End Sub
End Class

开发者ID:VB.NET开发者，项目名称:System.Security.Cryptography，代码行数:87，代码来源:RSAOAEPKeyExchangeFormatter

注：本文中的System.Security.Cryptography.RSAOAEPKeyExchangeFormatter类示例由纯净天空整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。