VB.NET NumberFormatInfo.CurrentInfo属性代码示例

OStack程序员社区-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.Globalization.NumberFormatInfo.CurrentInfo属性的典型用法代码示例。如果您正苦于以下问题：VB.NET NumberFormatInfo.CurrentInfo属性的具体用法？VB.NET NumberFormatInfo.CurrentInfo怎么用？VB.NET NumberFormatInfo.CurrentInfo使用的例子？那么恭喜您, 这里精选的属性代码示例或许可以为您提供帮助。您也可以进一步了解该属性所在类System.Globalization.NumberFormatInfo的用法示例。

在下文中一共展示了NumberFormatInfo.CurrentInfo属性的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: Main

' 导入命名空间
Imports System.Collections
Imports System.Globalization
Imports System.Reflection

Public Class Example : Implements IComparer
   Public Shared Sub Main()
      Dim nfi1 As NumberFormatInfo = NumberFormatInfo.CurrentInfo
      Dim nfi2 As NumberFormatInfo = CultureInfo.CurrentCulture.NumberFormat
      Console.WriteLine("Objects equal: {0}", nfi1.Equals(nfi2))
      Console.WriteLine("Equal references: {0}", Object.ReferenceEquals(nfi1, nfi2))
      Console.WriteLine()
      
      Dim props() As PropertyInfo = nfi1.GetType().GetProperties(BindingFlags.Instance Or BindingFlags.Public)
      Array.Sort(props, New Example)
      Console.WriteLine("Properties of NumberFormat.CurrentInfo object:")
      For Each prop In props
         If prop.PropertyType.IsArray Then
            Dim arr As Array = CType(prop.GetValue(nfi1), Array)
            Console.Write(String.Format("   {0}: ", prop.Name) + "{ ")
            Dim ctr As Integer = 0
            For Each item In arr
               Console.Write("{0}{1}", item, If(ctr = arr.Length - 1, " }", ", "))
               ctr += 1
            Next
            Console.WriteLine()
         Else
            Console.WriteLine("   {0}: {1}", prop.Name, prop.GetValue(nfi1))
        End If   
      Next      
   End Sub
   
   Private Function Compare(x As Object, y As Object) As Integer _
      Implements IComparer.Compare
      
      If x Is Nothing And y Is Nothing Then Return 0
      Dim px As PropertyInfo = TryCast(x, PropertyInfo)
      If px Is Nothing Then Return -1
      
      Dim py As PropertyInfo = TryCast(y, PropertyInfo)
      If py Is Nothing Then Return 1
      
      Return String.Compare(px.Name, py.Name)
   End Function
End Class

开发者ID:VB.NET开发者，项目名称:System.Globalization，代码行数:45，代码来源:NumberFormatInfo.CurrentInfo

输出：

Objects equal: True
Equal references: True

Properties of NumberFormat.CurrentInfo object:
CurrencyDecimalDigits: 2
CurrencyDecimalSeparator: .
CurrencyGroupSeparator: ,
CurrencyGroupSizes: { 3 }
CurrencyNegativePattern: 0
CurrencyPositivePattern: 0
CurrencySymbol: $
DigitSubstitution: None
IsReadOnly: True
NaNSymbol: NaN
NativeDigits: { 0, 1, 2, 3, 4, 5, 6, 7, 8, 9 }
NegativeInfinitySymbol: -Infinity
NegativeSign: -
NumberDecimalDigits: 2
NumberDecimalSeparator: .
NumberGroupSeparator: ,
NumberGroupSizes: { 3 }
NumberNegativePattern: 1
PercentDecimalDigits: 2
PercentDecimalSeparator: .
PercentGroupSeparator: ,
PercentGroupSizes: { 3 }
PercentNegativePattern: 0
PercentPositivePattern: 0
PercentSymbol: %
PerMilleSymbol: %
PositiveInfinitySymbol: Infinity
PositiveSign: +

注：本文中的System.Globalization.NumberFormatInfo.CurrentInfo属性示例由纯净天空整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。