VB.NET TripleDES.Create方法代码示例

OStack程序员社区-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.Security.Cryptography.TripleDES.Create方法的典型用法代码示例。如果您正苦于以下问题：VB.NET TripleDES.Create方法的具体用法？VB.NET TripleDES.Create怎么用？VB.NET TripleDES.Create使用的例子？那么恭喜您, 这里精选的方法代码示例或许可以为您提供帮助。您也可以进一步了解该方法所在类System.Security.Cryptography.TripleDES的用法示例。

在下文中一共展示了TripleDES.Create方法的4个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: TripleDESSample

' 导入命名空间
Imports System.Security.Cryptography
Imports System.Text
Imports System.IO

Module TripleDESSample

    Sub Main()
        Try
            ' Create a new TripleDES object to generate a key
            ' and initialization vector (IV).
            Using TripleDESalg As TripleDES = TripleDES.Create

                ' Create a string to encrypt.
                Dim sData As String = "Here is some data to encrypt."
                Dim FileName As String = "CText.txt"

                ' Encrypt text to a file using the file name, key, and IV.
                EncryptTextToFile(sData, FileName, TripleDESalg.Key, TripleDESalg.IV)

                ' Decrypt the text from a file using the file name, key, and IV.
                Dim Final As String = DecryptTextFromFile(FileName, TripleDESalg.Key, TripleDESalg.IV)

                ' Display the decrypted string to the console.
                Console.WriteLine(Final)
            End Using
        Catch e As Exception
            Console.WriteLine(e.Message)
        End Try
    End Sub


    Sub EncryptTextToFile(ByVal Data As String, ByVal FileName As String,
ByVal Key() As Byte, ByVal IV() As Byte)
        Try
            ' Create or open the specified file.
            Using fStream As FileStream = File.Open(FileName, FileMode.OpenOrCreate)

                ' Create a new TripleDES object.
                Using TripleDESalg As TripleDES = TripleDES.Create

                    ' Create a CryptoStream using the FileStream 
                    ' and the passed key and initialization vector (IV).
                    Using cStream As New CryptoStream(fStream, _
                        TripleDESalg.CreateEncryptor(Key, IV), _
                        CryptoStreamMode.Write)

                        ' Create a StreamWriter using the CryptoStream.
                        Using sWriter As New StreamWriter(cStream)

                            ' Write the data to the stream 
                            ' to encrypt it.
                            sWriter.WriteLine(Data)

                        End Using
                    End Using
                End Using
            End Using


        Catch e As CryptographicException
            Console.WriteLine("A Cryptographic error occurred: {0}", e.Message)
        Catch e As UnauthorizedAccessException
            Console.WriteLine("A file access error occurred: {0}", e.Message)
        End Try
    End Sub


    Function DecryptTextFromFile(ByVal FileName As String, ByVal Key() As Byte, ByVal IV() As Byte) As String
        Try
            Dim retVal As String
            ' Create or open the specified file. 
            Using fStream As FileStream = File.Open(FileName, FileMode.OpenOrCreate)

                ' Create a new TripleDES object.
                Using TripleDESalg As TripleDES = TripleDES.Create

                    ' Create a CryptoStream using the FileStream 
                    ' and the passed key and initialization vector (IV).
                    Using cStream As New CryptoStream(fStream, _
                        TripleDESalg.CreateDecryptor(Key, IV), CryptoStreamMode.Read)

                        ' Create a StreamReader using the CryptoStream.
                        Using sReader As New StreamReader(cStream)

                            ' Read the data from the stream 
                            ' to decrypt it.
                            retVal = sReader.ReadLine()
                        End Using
                    End Using
                End Using
            End Using

            Return retVal
        Catch e As CryptographicException
            Console.WriteLine("A Cryptographic error occurred: {0}", e.Message)
            Return Nothing
        Catch e As UnauthorizedAccessException
            Console.WriteLine("A file access error occurred: {0}", e.Message)
            Return Nothing
        End Try
    End Function
End Module

开发者ID:VB.NET开发者，项目名称:System.Security.Cryptography，代码行数:103，代码来源:TripleDES.Create

示例2: TripleDESPSample

' 导入命名空间
Imports System.Security.Cryptography
Imports System.Text
Imports System.IO

Module TripleDESPSample

    Sub Main()
        Try
            ' Create a new TripleDES object to generate a key
            ' and initialization vector (IV).
            Using TripleDESalg As TripleDES = TripleDES.Create

                ' Create a string to encrypt.
                Dim sData As String = "Here is some data to encrypt."

                ' Encrypt the string to an in-memory buffer.
                Dim Data As Byte() = EncryptTextToMemory(sData, TripleDESalg.Key, TripleDESalg.IV)

                ' Decrypt the buffer back to a string.
                Dim Final As String = DecryptTextFromMemory(Data, TripleDESalg.Key, TripleDESalg.IV)

                ' Display the decrypted string to the console.
                Console.WriteLine(Final)
            End Using

        Catch e As Exception
            Console.WriteLine(e.Message)
        End Try
    End Sub


    Function EncryptTextToMemory(ByVal Data As String, ByVal Key() As Byte, ByVal IV() As Byte) As Byte()
        Try
            Dim ret As Byte()
            ' Create a MemoryStream.
            Using mStream As New MemoryStream

                ' Create a new TripleDES object.
                Using tripleDESalg As TripleDES = TripleDES.Create

                    ' Create a CryptoStream using the MemoryStream 
                    ' and the passed key and initialization vector (IV).
                    Using cStream As New CryptoStream(mStream, _
                        tripleDESalg.CreateEncryptor(Key, IV), CryptoStreamMode.Write)

                        ' Convert the passed string to a byte array.
                        Dim toEncrypt As Byte() = New ASCIIEncoding().GetBytes(Data)

                        ' Write the byte array to the crypto stream and flush it.
                        cStream.Write(toEncrypt, 0, toEncrypt.Length)
                        cStream.FlushFinalBlock()

                        ' Get an array of bytes from the 
                        ' MemoryStream that holds the 
                        ' encrypted data.
                        ret = mStream.ToArray()
                    End Using
                End Using
            End Using

            ' Return the encrypted buffer.
            Return ret
        Catch e As CryptographicException
            Console.WriteLine("A Cryptographic error occurred: {0}", e.Message)
            Return Nothing
        End Try
    End Function


    Function DecryptTextFromMemory(ByVal Data() As Byte, ByVal Key() As Byte, ByVal IV() As Byte) As String
        Try
            Dim ret As String
            ' Create a new MemoryStream using the passed 
            ' array of encrypted data.
            Using msDecrypt As New MemoryStream(Data)

                ' Create a new TripleDES object.
                Using tripleDESalg As TripleDES = TripleDES.Create

                    ' Create a CryptoStream using the MemoryStream 
                    ' and the passed key and initialization vector (IV).
                    Using csDecrypt As New CryptoStream(msDecrypt, _
                         tripleDESalg.CreateDecryptor(Key, IV), CryptoStreamMode.Read)

                        ' Create buffer to hold the decrypted data.
                        Dim fromEncrypt(Data.Length - 1) As Byte

                        ' Read the decrypted data out of the crypto stream
                        ' and place it into the temporary buffer.
                        csDecrypt.Read(fromEncrypt, 0, fromEncrypt.Length)

                        'Convert the buffer into a string and return it.
                        ret = New ASCIIEncoding().GetString(fromEncrypt)
                    End Using
                End Using
            End Using
            Return ret

        Catch e As CryptographicException
            Console.WriteLine("A Cryptographic error occurred: {0}", e.Message)
            Return Nothing
        End Try
    End Function
End Module

开发者ID:VB.NET开发者，项目名称:System.Security.Cryptography，代码行数:105，代码来源:TripleDES.Create

示例3: TripleDESSample

' 导入命名空间
Imports System.Security.Cryptography
Imports System.Text
Imports System.IO

Module TripleDESSample

    Sub Main()
        Try
            ' Create a new TripleDES object to generate a key 
            ' and initialization vector (IV).  Specify one 
            ' of the recognized simple names for this 
            ' algorithm.
            Dim TripleDESalg As TripleDES = TripleDES.Create("TripleDES")

            ' Create a string to encrypt.
            Dim sData As String = "Here is some data to encrypt."
            Dim FileName As String = "CText.txt"

            ' Encrypt text to a file using the file name, key, and IV.
            EncryptTextToFile(sData, FileName, TripleDESalg.Key, TripleDESalg.IV)

            ' Decrypt the text from a file using the file name, key, and IV.
            Dim Final As String = DecryptTextFromFile(FileName, TripleDESalg.Key, TripleDESalg.IV)

            ' Display the decrypted string to the console.
            Console.WriteLine(Final)
        Catch e As Exception
            Console.WriteLine(e.Message)
        End Try
    End Sub


    Sub EncryptTextToFile(ByVal Data As String, ByVal FileName As String, ByVal Key() As Byte, ByVal IV() As Byte)
        Try
            ' Create or open the specified file.
            Dim fStream As FileStream = File.Open(FileName, FileMode.OpenOrCreate)

            ' Create a new TripleDES object.
            Dim TripleDESalg As TripleDES = TripleDES.Create

            ' Create a CryptoStream using the FileStream 
            ' and the passed key and initialization vector (IV).
            Dim cStream As New CryptoStream(fStream, _
                                           TripleDESalg.CreateEncryptor(Key, IV), _
                                           CryptoStreamMode.Write)

            ' Create a StreamWriter using the CryptoStream.
            Dim sWriter As New StreamWriter(cStream)

            ' Write the data to the stream 
            ' to encrypt it.
            sWriter.WriteLine(Data)

            ' Close the streams and
            ' close the file.
            sWriter.Close()
            cStream.Close()
            fStream.Close()
        Catch e As CryptographicException
            Console.WriteLine("A Cryptographic error occurred: {0}", e.Message)
        Catch e As UnauthorizedAccessException
            Console.WriteLine("A file error occurred: {0}", e.Message)
        End Try
    End Sub


    Function DecryptTextFromFile(ByVal FileName As String, ByVal Key() As Byte, ByVal IV() As Byte) As String
        Try
            ' Create or open the specified file. 
            Dim fStream As FileStream = File.Open(FileName, FileMode.OpenOrCreate)

            ' Create a new TripleDES object.
            Dim TripleDESalg As TripleDES = TripleDES.Create

            ' Create a CryptoStream using the FileStream 
            ' and the passed key and initialization vector (IV).
            Dim cStream As New CryptoStream(fStream, _
                                            TripleDESalg.CreateDecryptor(Key, IV), _
                                            CryptoStreamMode.Read)

            ' Create a StreamReader using the CryptoStream.
            Dim sReader As New StreamReader(cStream)

            ' Read the data from the stream 
            ' to decrypt it.
            Dim val As String = sReader.ReadLine()

            ' Close the streams and
            ' close the file.
            sReader.Close()
            cStream.Close()
            fStream.Close()

            ' Return the string. 
            Return val
        Catch e As CryptographicException
            Console.WriteLine("A Cryptographic error occurred: {0}", e.Message)
            Return Nothing
        Catch e As UnauthorizedAccessException
            Console.WriteLine("A file error occurred: {0}", e.Message)
            Return Nothing
        End Try
    End Function
End Module

开发者ID:VB.NET开发者，项目名称:System.Security.Cryptography，代码行数:105，代码来源:TripleDES.Create

示例4: TripleDESPSample

' 导入命名空间
Imports System.Security.Cryptography
Imports System.Text
Imports System.IO

Module TripleDESPSample

    Sub Main()
        Try
            ' Create a new TripleDES object to generate a key 
            ' and initialization vector (IV).  Specify one 
            ' of the recognized simple names for this 
            ' algorithm.
            Dim TripleDESalg As TripleDES = TripleDES.Create("TripleDES")

            ' Create a string to encrypt.
            Dim sData As String = "Here is some data to encrypt."

            ' Encrypt the string to an in-memory buffer.
            Dim Data As Byte() = EncryptTextToMemory(sData, TripleDESalg.Key, TripleDESalg.IV)

            ' Decrypt the buffer back to a string.
            Dim Final As String = DecryptTextFromMemory(Data, TripleDESalg.Key, TripleDESalg.IV)

            ' Display the decrypted string to the console.
            Console.WriteLine(Final)
        Catch e As Exception
            Console.WriteLine(e.Message)
        End Try
    End Sub


    Function EncryptTextToMemory(ByVal Data As String, ByVal Key() As Byte, ByVal IV() As Byte) As Byte()
        Try
            ' Create a MemoryStream.
            Dim mStream As New MemoryStream

            ' Create a new TripleDES object.
            Dim tripleDESalg As TripleDES = TripleDES.Create

            ' Create a CryptoStream using the MemoryStream 
            ' and the passed key and initialization vector (IV).
            Dim cStream As New CryptoStream(mStream, _
                                            tripleDESalg.CreateEncryptor(Key, IV), _
                                            CryptoStreamMode.Write)

            ' Convert the passed string to a byte array.
            Dim toEncrypt As Byte() = New ASCIIEncoding().GetBytes(Data)

            ' Write the byte array to the crypto stream and flush it.
            cStream.Write(toEncrypt, 0, toEncrypt.Length)
            cStream.FlushFinalBlock()

            ' Get an array of bytes from the 
            ' MemoryStream that holds the 
            ' encrypted data.
            Dim ret As Byte() = mStream.ToArray()

            ' Close the streams.
            cStream.Close()
            mStream.Close()

            ' Return the encrypted buffer.
            Return ret
        Catch e As CryptographicException
            Console.WriteLine("A Cryptographic error occurred: {0}", e.Message)
            Return Nothing
        End Try
    End Function


    Function DecryptTextFromMemory(ByVal Data() As Byte, ByVal Key() As Byte, ByVal IV() As Byte) As String
        Try
            ' Create a new MemoryStream using the passed 
            ' array of encrypted data.
            Dim msDecrypt As New MemoryStream(Data)

            ' Create a new TripleDES object.
            Dim tripleDESalg As TripleDES = TripleDES.Create

            ' Create a CryptoStream using the MemoryStream 
            ' and the passed key and initialization vector (IV).
            Dim csDecrypt As New CryptoStream(msDecrypt, _
                                              tripleDESalg.CreateDecryptor(Key, IV), _
                                              CryptoStreamMode.Read)

            ' Create buffer to hold the decrypted data.
            Dim fromEncrypt(Data.Length - 1) As Byte

            ' Read the decrypted data out of the crypto stream
            ' and place it into the temporary buffer.
            csDecrypt.Read(fromEncrypt, 0, fromEncrypt.Length)

            'Convert the buffer into a string and return it.
            Return New ASCIIEncoding().GetString(fromEncrypt)
        Catch e As CryptographicException
            Console.WriteLine("A Cryptographic error occurred: {0}", e.Message)
            Return Nothing
        End Try
    End Function
End Module

开发者ID:VB.NET开发者，项目名称:System.Security.Cryptography，代码行数:101，代码来源:TripleDES.Create

注：本文中的System.Security.Cryptography.TripleDES.Create方法示例由纯净天空整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。