VB.NET IEditableObject接口代码示例

OStack程序员社区-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.ComponentModel.IEditableObject接口的典型用法代码示例。如果您正苦于以下问题：VB.NET IEditableObject接口的具体用法？VB.NET IEditableObject怎么用？VB.NET IEditableObject使用的例子？那么恭喜您, 这里精选的接口代码示例或许可以为您提供帮助。

在下文中一共展示了IEditableObject接口的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: Customer

Public Class Customer
    Implements IEditableObject

    Structure CustomerData
        Friend id As String
        Friend firstName As String
        Friend lastName As String
    End Structure 

    Public parent As CustomersList
    Private custData As CustomerData
    Private backupData As CustomerData
    Private inTxn As Boolean = False


    ' Implements IEditableObject
    Sub BeginEdit() Implements IEditableObject.BeginEdit
        Console.WriteLine("Start BeginEdit")
        If Not inTxn Then
            Me.backupData = custData
            inTxn = True
            Console.WriteLine(("BeginEdit - " + Me.backupData.lastName))
        End If
        Console.WriteLine("End BeginEdit")
    End Sub 


    Sub CancelEdit() Implements IEditableObject.CancelEdit
        Console.WriteLine("Start CancelEdit")
        If inTxn Then
            Me.custData = backupData
            inTxn = False
            Console.WriteLine(("CancelEdit - " + Me.custData.lastName))
        End If
        Console.WriteLine("End CancelEdit")
    End Sub 


    Sub EndEdit() Implements IEditableObject.EndEdit
        Console.WriteLine(("Start EndEdit" + Me.custData.id + Me.custData.lastName))
        If inTxn Then
            backupData = New CustomerData()
            inTxn = False
            Console.WriteLine(("Done EndEdit - " + Me.custData.id + Me.custData.lastName))
        End If
        Console.WriteLine("End EndEdit")
    End Sub 


    Public Sub New(ByVal ID As String)
        Me.custData = New CustomerData()
        Me.custData.id = ID
        Me.custData.firstName = ""
        Me.custData.lastName = ""
    End Sub 


    Public ReadOnly Property ID() As String
        Get
            Return Me.custData.id
        End Get
    End Property


    Public Property FirstName() As String
        Get
            Return Me.custData.firstName
        End Get
        Set(ByVal Value As String)
            Me.custData.firstName = Value
            Me.OnCustomerChanged()
        End Set
    End Property


    Public Property LastName() As String
        Get
            Return Me.custData.lastName
        End Get
        Set(ByVal Value As String)
            Me.custData.lastName = Value
            Me.OnCustomerChanged()
        End Set
    End Property


    Friend Property Parents() As CustomersList
        Get
            Return Parent
        End Get
        Set(ByVal Value As CustomersList)
            parent = Value
        End Set
    End Property


    Private Sub OnCustomerChanged()
        If Not inTxn And (Parent IsNot Nothing) Then
            Parent.CustomerChanged(Me)
        End If
    End Sub 

    
    Public Overrides Function ToString() As String
        Dim sb As New StringWriter()
        sb.Write(Me.FirstName)
        sb.Write(" ")
        sb.Write(Me.LastName)
        Return sb.ToString()
    End Function 
End Class

开发者ID:VB.NET开发者，项目名称:System.ComponentModel，代码行数:111，代码来源:IEditableObject

注：本文中的System.ComponentModel.IEditableObject接口示例由纯净天空整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。