// in build.gradle
buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.1.2'
        classpath 'com.github.gfx.ribbonizer:ribbonizer-plugin:2.1.0'
    }
}

// in app/build.gradle
apply plugin: 'com.github.gfx.ribbonizer'

android {
    // ...

    buildTypes {
        debug {/*debuggable build, which will ribbonized automatically*/}
        beta {
            //debuggable build which will automatically ribbonized.
            debuggable true
        }
        canary {
            //non-debuggable build which will no automatically ribbonized.
            //But, we force one of its flavors. See `ribbonizer` for how-to
            debuggable false
        }
        release {/*non-debuggable build. Will not be rebbonized automatically*/}
    }

    productFlavors {
        local {}
        qa {}
        staging {}
        production {}
    }
}

ribbonizer {
    // "manifest application[android:icon]" is automatically added to the list
    iconNames "@drawable/ic_notification", "@drawable/widget_preview"

    builder { variant, iconFile ->
        // change ribbon colors by product flavors
        if (variant.flavorName == "local") {
            return grayRibbonFilter(variant, iconFile)
        } else if (variant.flavorName == "qa") {
            // customColorRibbonFilter allows setting any color code
            def filter = customColorRibbonFilter(variant, iconFile, "#00C89C")
            // Finer control of the label text can be achieved by setting it manually, or set to
            // null for an unlabelled ribbon. The default is to use the flavor name.
            filter.label = "QA" + variant.versionCode
            return filter
        } else if (variant.flavorName == "staging") {
            return yellowRibbonFilter(variant, iconFile)
        } else if (variant.buildType.name == "debug") {
            if (variant.flavorName == "production") {
                // Particular configurations can be skipped by returning no filters
                return null
            }
            else {
                // Other filters can be applied, as long as they implement Consumer<BufferedImage>
                return grayScaleFilter(variant, iconFile)
            }
        } else {
            return greenRibbonFilter(variant, iconFile)
        }
    }

    //Although `canary` build-type is marked as `non-debuggable`
    //we can still force specific variants to be ribbonized:
    forcedVariantsNames "localCanary"
}