•     TList<T>，TObjectList<T: Class>
•     TQueue<T>，TObjectQueue<T: Class>
•     TStack<T>，TObjectStack<T: Class>
•     TDictionary<T>，TObjectDictionary<T: Class>

上面的泛型容器類別使用方法和前面介紹的TList差不多，只是不同的泛型容器類別提供了對於其中包含的元素不同的運算法則。
其中需要稍為解釋的是為什麼每一個泛型容器類別都有一個對應的Object泛型容器類別?例如TList<T>既然已經能夠處理任何的型態，包含了類別型態，那麼為什麼還需要TObjectList<T>呢? 沒錯TList<T>是能夠放入任何的資料型態/類別型態，而TList<T>和TObjectList<T>的差別是TObjectList<T>能夠自動管理在TObjectList<T>中包含的物件的生命週期，簡單的說TObjectList<T>能夠在本身的樣例釋放時自動釋放它管理的所有物件樣例。
例如TObjectList<T>有如下的建構函式原型:
    constructor Create(AOwnsObjects: Boolean = True); overload;
我們可以看到它的建構函式接受一個AOwnsObjects的參數，它的內定值為True，這代表一旦開發人員建立了TObjectList<T>物件之後，如果在其中放入物件樣例，那麼TObjectList<T>物件在被釋放時也會釋放它包含的所有物件樣例。例如假設現在我們有一個TProduct類別，如果我們使用TObjectList<T>來管理TProduct類別，那麼可以使用如下的程式碼:
var
  aProduct: TProduct;
  ptList : TObjectList<TProduct>;
begin
  …
  ptList := TObjectList<TProduct>.create;
  try
    ptList.Add(TProduct.create(‘Delphi’));
    ptList.Add(TProduct.create(‘BCB’));
    ptList.Add(TProduct.create(‘JBuilder’));
    …
  finally
    ptList.Free;
  end;
  ..
那麼當上面的程式碼執行到ptList.Free時，ptList中包含的3個TProduct物件也會自動被釋放。當然，如果您不希望TObjectList<T>自動刪除其中管理的物件，那麼在建立時傳遞False給它的建構函式做為參數，或是在建立之後設定它的OwnsObjects特性值為False也可以。
有了這些基本的知識之後，讓我們使用一個簡單的範例來說明如何使用TObjectList<T>和TEnumerator<T>，TDictionary<T,T>以及TComparer<T>等泛型容器類別，在讀者瞭解了如何使用這四個類別之後對於使用其他的泛型容器類別應該就非常簡單了。

使用TObjectList和TEnumerator

為了說明起見，讓我們定義一個TProduct類別如下:
  TProduct = class
  private
    FName : string;
    FCode : String;
    FCategory : string;
    FVersion : double;
  public
    constructor Create(sName, sCode : string; dVersion : double; sCategory : string = 'Delphi');
    destructor Destroy; override;
    function GetName : string;
    function GetCode : string;
    function GetCategory : string;
    function GetVersion : double;
  end;

接著我們建立一個TObjectList<TProduct>:
procedure TForm17.FormCreate(Sender: TObject);
begin
  glProduct := TObjectList<TProduct>.Create(True);
end;
Delphi 2009的泛型容器類別是定義在一個新的程式單元Generics.Collections之中，因此當然要記得先在uses句子中加入使用Generics.Collections。
接著其中建立一些範例TProduct物件:
procedure TForm17.CreateTempProducts;
begin
  glProduct.Add(TProduct.Create('Delphi 2009', 'Tiburon', 12.0));
  glProduct.Add(TProduct.Create('Delphi 2007', 'Highlander', 11.5));
  glProduct.Add(TProduct.Create('Delphi 2006', 'Dexter', 11.0));

  glProduct.Add(TProduct.Create('C++Builder 2009', 'Tiburon', 12.0, 'BCB'));
  glProduct.Add(TProduct.Create('C++Builder 6', 'Riptide', 6.0, 'BCB'));
  glProduct.Add(TProduct.Create('C++Builder 5', 'Rampage', 5.0, 'BCB'));
end;

在一般使用泛型容器類別時，最常應用的情形是需要從泛型容器類別中一一取出它包含的元素來處理。在這種應用中大都是使用TEnumerator物件來幫助開發人員存取其中的元素，一般來說泛型容器類別都會提供GetEnumerator方法讓開發人員取得泛型容器類別對應的TEnumerator物件，再藉由TEnumerator物件來一一存取其中的元素。
在Delphi 2009中Tenumerator<T>有如下的宣告:
  TEnumerator<T> = class abstract
  protected
    function DoGetCurrent: T; virtual; abstract;
    function DoMoveNext: Boolean; virtual; abstract;
  public
    property Current: T read DoGetCurrent;
    function MoveNext: Boolean;
  end;

其中開發人員藉由呼叫MoveNext方法來判斷是否還有未存取的元素，而Current特性可以讓開發人員取得目前的元素。
在TList<T>類別中也定義了GetEnumerator方法可以取得它相關的TEnumerator物件:
    function GetEnumerator: TEnumerator; reintroduce;

例如假設現在我們希望把剛才加入的所有TProduct物件顯示在TListBox中，那麼就可以使用如下的程式碼:
procedure TForm17.btn使用EnumeratorClick(Sender: TObject);
var
  aEnum : TEnumerator<TProduct>;
begin
  aEnum := glProduct.GetEnumerator;
  DisplayProducts(aEnum);
end;

首先我們呼叫TObjectList的GetEnumerator取得TEnumerator物件，由於這個TEnumerator物件是存取TProduct物件，因此它的型態定義是TEnumerator<TProduct>，也就是把<T>代換成<TProduct>。
接著DisplayProducts就藉由TEnumerator物件進入while迴圈，如果TEnumerator物件的MoveNext持續回傳True就代表尚有未存取的TProduct。在while迴圈中開發人員可以藉由TEnumerator物件的Current特性值取得目前要處理的TProduct物件再進行後續的處理工作。
procedure TForm17.DisplayProducts(aEnum: TEnumerator<TProduct>);
begin
  lb產品資料.Items.Clear;
  while (aEnum.MoveNext) do
  begin
    lb產品資料.Items.Add(aEnum.Current.GetName + ' : ' + aEnum.Current.GetCode);
  end;
end;