// preCaseLess: 不区分大小写, 相当于其他语言中的 i
var
  reg: TPerlRegEx;
begin
  reg := TPerlRegEx.Create(nil);

  reg.Subject := 'abc ABC aBc';
  reg.RegEx   := 'abc';
  reg.Replacement := '◆';

  reg.Options := [preCaseLess]; //选项是集合类型的

  reg.ReplaceAll;

  ShowMessage(reg.Subject); //返回: ◆ ◆ ◆

  FreeAndNil(reg);
end;
--------------------------------------------------------------------------------

// preAnchored: 只匹配字符串开始, 相当于 ^, 不过还是有区别的
var
  reg: TPerlRegEx;
begin
  reg := TPerlRegEx.Create(nil);

  reg.Subject := 'abc abc abc';
  reg.RegEx   := 'abc';
  reg.Replacement := '◆';

  reg.Options := [preAnchored]; //指定: preAnchored

  reg.ReplaceAll;

  ShowMessage(reg.Subject); //返回: ◆ abc abc

  FreeAndNil(reg);
end;
{preAnchored 选项和 ^ 的区别:
  1、任何情况下, preAnchored 只匹配字符串开头;
  2、在 preMultiLine 选项模式下, ^ 还能匹配每行的开头;
  3、^ 还有其他用途.
}
--------------------------------------------------------------------------------

// preDollarEndOnly: 让 $ 只匹配字符串结尾
var
  reg: TPerlRegEx;
begin
  reg := TPerlRegEx.Create(nil);

  reg.Subject := 'abc abc abc'#13#10 +
                 'abc abc abc'#13#10 +
                 'abc abc abc';
  reg.RegEx   := 'abc$';  //当然需要有 $
  reg.Replacement := '◆';

  reg.Options := [preDollarEndOnly]; //指定: preDollarEndOnly

  reg.ReplaceAll;

  ShowMessage(reg.Subject);
{返回:
  abc abc abc
  abc abc abc
  abc abc ◆
}

  FreeAndNil(reg);
end;
--------------------------------------------------------------------------------

// preMultiLine: 多行匹配, 相当于其他语言中的 m
var
  reg: TPerlRegEx;
begin
  reg := TPerlRegEx.Create(nil);

  reg.Subject := 'abc abc abc'#13#10 +
                 'abc abc abc'#13#10 +
                 'abc abc abc';
  reg.RegEx   := '^abc';
  reg.Replacement := '◆';

  reg.Options := [preMultiLine]; //指定: preMultiLine

  reg.ReplaceAll;

  ShowMessage(reg.Subject);
{返回:
  ◆ abc abc
  ◆ abc abc
  ◆ abc abc
}
{如果不指定 preMultiLine 将返回:
  ◆ abc abc
  abc abc abc
  abc abc abc
}

  FreeAndNil(reg);
end;
{
  1、preMultiLine 是对 ^ 和 $ 的扩展使用;
  2、在指定了 [preAnchored] 或 [preDollarEndOnly] 的情况下无效.
}
--------------------------------------------------------------------------------

// preSingleLine: 让特殊符号 . 能够匹配换行符 (. 的本意是匹配换行符以外的任意字符)
var
  reg: TPerlRegEx;
begin
  reg := TPerlRegEx.Create(nil);

  reg.Subject := 'aaa;bbb;'#13#10 +
                 '111;222;'#13#10 +
                 'AAA;BBB;';
  reg.RegEx   := ';.';
  reg.Replacement := '◆';

  reg.Options := [preSingleLine]; //指定: preSingleLine

  reg.ReplaceAll;

  ShowMessage(reg.Subject);
{返回:
  aaa◆bb◆
  111◆22◆
  AAA◆BB;
}
{如果不指定 preMultiLine 将返回:
  aaa◆bb;
  111◆22;
  AAA◆BB;
}

  FreeAndNil(reg);
end;
--------------------------------------------------------------------------------

// preUnGreedy: 指定为非贪婪模式
var
  reg: TPerlRegEx;
begin
  reg := TPerlRegEx.Create(nil);

  reg.Subject := '《Delphi》and《C++Builder》';
  reg.RegEx   := '《.*》';

  reg.Replacement := '◆';

  reg.Options := [preUnGreedy]; //指定: preUnGreedy
  { 在本例中, reg.RegEx := '《.*?》'; 可以达到同样的效果}

  reg.ReplaceAll;

  ShowMessage(reg.Subject); //返回: ◆and◆ ; 如果不指定 preUnGreedy, 将返回: ◆

  FreeAndNil(reg);
end;
--------------------------------------------------------------------------------

// preExtended: 指定为扩展模式
var
  reg: TPerlRegEx;
begin
  reg := TPerlRegEx.Create(nil);

  reg.Subject := 'Delphi C++Builder';
  reg.RegEx   := 'i\x20C'; // \x20 是用十六进制的方式表示的空格

  reg.Replacement := '◆';

  reg.Options := [preExtended]; //指定: preExtended

  reg.ReplaceAll;

  ShowMessage(reg.Subject); //返回: Delph◆++Builder

  FreeAndNil(reg);
end;
{preExtended 是最复杂的一个选项:
  1、它会忽略表达式中的空白, 譬如: 本例中的表达式如果是 'i C' 将不会匹配成功;
  2、空白要用相应的十六进制表示, 譬如用 \x20 表示空格;
  3、把表达式中从 # 到行尾的部分当作注释而被忽略;
  4、如果要使用 # ,需要用 \# 代替;
  5、表达式的标准注释是: (?#...) 及其中 # 后面的内容均为注释, 不管指定 preExtended 与否
}
--------------------------------------------------------------------------------
关于选项 preExtra:

如果表达式中需要特殊字符 ^ $ ( ) [ ] { } . ? + * | \ 时, 需要加转义符号 \ ;
默认状态下, 其他字符前面添加了 \ 会识别为字符本身;
preExtra 选项应该就是禁止这种情况的, 也就是不要在非特殊字符前加 \ ;
但测试效果 ... 也许是我没弄明白!

还有三个状态选项: preNotBOL, preNotEOL, preNotEmpty

reg.State := [preNotBOL] 是让标记开始的 ^ 无效;
reg.State := [preNotEOL] 是让标记结尾的 $ 无效;
reg.State := [preNotEmpty] 没弄明白!

另外这些选择是可以组合使用的, 譬如:

reg.Options := [preCaseLess, preMultiLine, preSingleLine];
reg.State := [preNotBOL, preNotEOL];