首先申明:我是菜鸟,我只不过想把困绕了我很长时间的问题的解决方案发表出来，免得以后我又忘记,同时给还不知道这些小知识的同僚一些帮助。各位不要笑我的浅薄。同时为了表示我的低级，我会很罗嗦的讲一些基本的东西，这些都是我的理解,很不准确。

用我的方法来控制其他程序窗体上的窗口控件，必须先了解什么是回调函数。我的理解是这样的：

回调函数写出来不是自己的程序去调用的，反而是让其他的东西去调用，比如windows操作系统，比如其他的程序等等之类的。但是什么时候被调用却不知道了。回调函数一般是按照调用者的要求定义好参数和返回值的类型，你向调用者提供你的回调函数的入口地址，然后调用者有什么事件发生的时候就可以随时按照你提供的地址调用这个函数通知你，并按照预先规定好的形式传递参数。所以很多人打比方，说回调函数还真有点像您随身带的BP机：告诉别人号码，在它有事情时Call您！

所以一个回调函数写出来之后，一定有个注册的动作，就是告诉调用者，你怎么样找到我写的函数。某些Windows API 函数会要求以回调函数地址作为其参数之一，例如SetTimer 、LineDDA 、EnumObjects，以及我们下面要用到的EnumWindows。

在Delphi里声明一个回调函数的格式很简单，例如：

function EnumWindowsProc(AhWnd:LongInt;lParam:LongInt):boolean;stdcall;

首先是函数名称可以随便乱取，但函数参数的类型一般不得乱来，其顺序，数据类型等都有规定的，因为这些都是让其他程序调用的，他们已经规定好了的，但参数名称可以随便乱叫。注意后面一定要带上“stdcall”，

stdcall是标准调用,也就是说采用标准windows参数传递方式来调用函数。

编写函数体就很简单了，利用传递过来的参数就可以了，只要记住，这些参数是别人送给你的，你只要知道这些参数代表了什么意思。

再看个向调用者注册回调函数入口地址的函数。
function EnumWindows(lpEnumFunc: TFNWndEnumProc; lParam: LPARAM): BOOL; stdcall;

TFNWndEnumProc其实就是指针类型。其中的lpEnumFunc就是回调函数的入口地址了。

下面是调用EnumWindows的格式：
EnumWindows(@EnumWindowsProc,0);

通过向系统注册回调函数的入口地址，系统就能在需要的时候，调用回调函数，传递参数给它，也许这些参数就是我们想要的。

EnumWindows函数的功能是：枚举屏幕上所有程序中的顶层窗口，将窗口句柄以参数的形式传递给回调函数。找到一个窗口，就调用一次回调函数。枚举结束的条件是：要么枚举完所有的窗口，要么回调函数返回False。

lParam: LPARAM参数是程序定义的值，这个值被传递到回调函数。

回过头来再看一下EnumWindowsProc：

function EnumWindowsProc(AhWnd:LongInt;lParam:LongInt):boolean;stdcall;

当系统找到了一个窗口后，就开始调用这个回调函数，将窗口的句柄作为第一个参数传递过来，将在EnumWindows中lParam: LPARAM这个程序定义的值作为第二个参数传递过来。

所以我们可以在EnumWindowsProc函数中利用传递过来的两个参数来做某些处理了。

下面我们新建一个程序列举系统中所有程序的顶层窗口，我们要得到窗口的标题，要得到窗口类名称。

得到窗口标题用：

function GetWindowText(hWnd: HWND; lpString: PChar; nMaxCount: Integer): Integer; stdcall;

该函数功能是将窗口句柄为hWnd的窗口的标题拷入到一个缓冲区lpString。nMaxCount是拷入缓冲区内的最大的字符数。

要得到窗口标题还可以发送消息：WM_GETTEXT，其实GetWindowText就是发送WM_GETTEXT消息的。

要得到窗口类名称用：

function GetClassName(hWnd: HWND; lpClassName: PChar; nMaxCount: Integer): Integer; stdcall;

其参数意义和上面的函数差不多。不详细解释了。

我们先编写回调函数：EnumWindowsProc。现在告诉自己，我们已经有了两个参数的值了。这两个参数是系统给我们的.

为了显示窗口标题和类名，我们用一个TMemo控件。

先在interface部分声明函数。

function EnumWindowsProc(AhWnd:LongInt;AForm:TForm1):boolean;stdcall;

注意我将第二个参数改了，不要紧，到时候调用的时候注意看。

然后在implementation部分定义函数：
function EnumWindowsProc(AhWnd:LongInt;AForm:TForm1):boolean;
var
lpszClassName,lpszWindowText:array[0..254] of char; //定义两个缓冲区。
begin
GetWindowText(AhWnd,lpszWindowText,254);//得到窗口标题
GetClassName(AhWnd,lpszClassName,254);//得到窗口类名。
Aform.memo1.lines.add(StrPas(lpszWindowText));
Aform.memo1.lines.add(StrPas(lpszClassName));
Aform.memo1.lines.add('--------------------');
Result:=True;
end;

接着需要做的就是调用EnumWindows函数，注册回调函数入口地址，让系统调用回调函数，列举窗口了。所以再添加一个TButton: btn_listwindow
procedure TForm1.btn_listwindowClick(Sender: TObject);
begin
EnumWindows(@EnumWindowsProc,LongInt(self));
end;

程序清单如下：
unit Unit1;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls;

type
TForm1 = class(TForm)
Memo1: TMemo;
btn_listwindow: TButton;
procedure btn_listwindowClick(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;

var
Form1: TForm1;

function EnumWindowsProc(AhWnd:LongInt;AForm:TForm1):boolean;stdcall;

implementation
{$R *.dfm}
function EnumWindowsProc(AhWnd:LongInt;AForm:TForm1):boolean;
var
lpszClassName,lpszWindowText:array[0..254] of char;
begin
GetWindowText(AhWnd,lpszWindowText,254);
GetClassName(AhWnd,lpszClassName,254);
Aform.memo1.lines.add(StrPas(lpszWindowText));
Aform.memo1.lines.add(StrPas(lpszClassName));
Aform.memo1.lines.add('--------------------');
Result:=True;
end;

procedure TForm1.btn_listwindowClick(Sender: TObject);
begin
EnumWindows(@EnumWindowsProc,LongInt(self));
end;

end.
F9，运行，看看结果。最好是F7单步跟踪调试一下，看看回调函数是怎么被调用的。

有了回调函数的概念及上面的例子,我们可以继续了。其实想要找到一个标题已知的窗口句柄,用一个API函数就可以了:FindWindow.

其函数原形是:

function FindWindow(lpClassName, lpWindowName: PChar): HWND; stdcall;

lpClassName:窗口类名.如果只知道标题,可以为空.窗口类名可以用很多工具获得.如winsignt32.
lpWindowName:窗口标题.

调用方式举例:

var wndhwnd:HWND;
wndhwnd:=FindWindow(nil,'某窗口标题');
if wndhwnd<>0 then file://找到此窗口句柄.
begin
xxxxx
end
else begin
MessageBox(self.handle,'没找到该窗口句柄','提示',0);
end;

有了这个窗口句柄,就离我们的初始目的不远了:控制其他窗体上的窗口控件.

同样,首先要得到其他窗体上窗口控件的句柄.我们用这个API函数:EnumChildWindows.

其函数原形是:
function EnumChildWindows(hWndParent: HWND; lpEnumFunc: TFNWndEnumProc;
lParam: LPARAM): BOOL; stdcall;

这个函数和EnumWindow函数很有些想象.其作用也很相似.它的功能就是列举窗口句柄为hWndParent的窗体上所有的窗口控件的句柄.同样也是以回调函数参数的形式给出的.

我们再举一个实际的例子,来说明这个函数的用法.程序的功能是让用户输入一个窗口标题,然后调用FindWindow函数找到此窗口句柄.通过这个句柄,我们在一个Memo里显示该窗口上所有的窗口控件．

同样先编写回调函数．
function EnumChildWndProc(AhWnd:LongInt;
AlParam:lParam):boolean;stdcall;
var
WndClassName: array[0..254] of Char;
WndCaption: array[0..254] of Char;
begin
GetClassName(AhWnd,wndClassName,254);
GetWindowText(aHwnd,WndCaption,254);
with form1.memo1 do
begin
lines.add( string(wndClassName));
lines.add( string(wndCaption));
lines.add('-------');
end;
result:=true;
end;


然后在一事件里调用EnumChildWindows函数．
procedure TForm1.Button1Click(Sender: TObject);
var
hWnd:LongInt;
begin
memo1.Lines.Clear;
Memo1.Lines.Add(Edit1.Text+' 有如下控件类名称');
hWnd:=FindWindow(nil,pchar(Edit1.Text));
if hWnd<>0 then
begin
EnumChildWindows(hWnd,@EnumChildWndProc,0);
end
else MessageBox(self.handle,'没找到该窗口句柄','提示',0);
end;

程序清单如下：
unit Unit1;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls;

type
TForm1 = class(TForm)
Memo1: TMemo; file://用来显示找到的控件
Label1: TLabel;　
Edit1: TEdit;　　file://输入标题.
Button1: TButton; 
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;

var
Form1: TForm1;

function EnumChildWndProc(AhWnd:LongInt;
AlParam:lParam):boolean;stdcall;

implementation


{$R *.dfm}
function EnumChildWndProc(AhWnd:LongInt;
AlParam:lParam):boolean;stdcall;
var
WndClassName: array[0..254] of Char;
WndCaption: array[0..254] of Char;
begin
GetClassName(AhWnd,wndClassName,254);
GetWindowText(aHwnd,WndCaption,254);
with form1.memo1 do
begin
lines.add( string(wndClassName));
lines.add( string(wndCaption));
lines.add('-------');
end;
result:=true;
end;


procedure TForm1.Button1Click(Sender: TObject);
var
hWnd:LongInt;
begin
memo1.Lines.Clear;
Memo1.Lines.Add(Edit1.Text+' 有如下控件类名称');
hWnd:=FindWindow(nil,pchar(Edit1.Text));
if hWnd<>0 then
begin
EnumChildWindows(hWnd,@EnumChildWndProc,0);
end
else MessageBox(self.handle,'没找到该窗口句柄','提示',0);
end;

end.


有了控件句柄,我们当然就可以随心所欲了.比如:

SendMessage(hWnd,WM_SETTEXT,0,LongInt(Pchar('哈哈！')));就可以给控件发送文本.其他还可以发送不同的消息可以做很多事情.

最后总结一下：在最后的例程中没有改变窗体控件的代码，可以向它发消息，这里自己可以把代码加在函数调用的后面，如上面的消息就是把句柄为hWnd的控件的TEXT改为了哈哈！