var
    InterlockedCrit: TRTLCriticalSection;
procedure InterlockedIncrement(var aValue: Integer);
begin
    EnterCriticalSection(InterlockedCrit);
    Inc(aValue);
    LeaveCriticalSection(InterlockedCrit);
end;

EnterCriticalSection( InterlockedCrit );
try
    //操作临界区数据
finally
    LeaveCriticalSection( InterlockedCrit );
end;

procedure TThread.Synchronize(Method: TTheadMethod);
begin
    FSynchronize.FThread:= Self;
    FSynchronize.FSynchronize.Exception:= nil;
    FSynchronize..FMethod:= Method;
    Synchronize(@FSynchronize);
end;

PSynchronizeRecord= ^TSynchronizeRecord;
TSynchronizeRecord = record
    FThread: TObject;
    FMethod: TThreadMethod;
    FSynchronizeException: TObject;
end;

class procedure TThread.Synchronize(ASyncRec: PSynchronizeRecord);
var
  SyncProc: TSyncProc;
begin
  if GetCurrentThreadID = MainThreadID then
    ASyncRec.FMethod
    // 首先是判断当前线程是否是主线程，如果是，则简单地执行同步方法后返回。
  else
  begin
    SyncProc.Signal := CreateEvent(nil, True, False, nil);
    { 通过局部变量SyncProc记录线程交换数据（参数）和一个Event Handle，其记录结构如下：
      TSyncProc = record
      SyncRec: PSynchronizeRecord;
      Signal: THandle;
      end; }
    try
      EnterCriticalSection(ThreadLock);
      {
        接着进入临界区（通过全局变量ThreadLock进行，因为同时只能有一个线程进入Synchronize状态，所以可以用全局变量记录）
      }
      try
        { 然后就是把这个记录数据存入SyncList这个列表中（如果这个列表不存在的话，则创建它）。 }
        if SyncList = nil then
          SyncList := TList.Create;
        //
        SyncProc.SyncRec := ASyncRec;
        SyncList.Add(@SyncProc);
        { 再接下就是调用SignalSyncEvent，其代码在前面介绍TThread的构造函数时已经介绍过了，它的功能就是简单地将SyncEvent作一个Set的操作。关于这个SyncEvent的用途，将在后面介绍WaitFor时再详述。 }
        SignalSyncEvent;
        { 接下来就是最主要的部分了：调用WakeMainThread事件进行同步操作。WakeMainThread是一个TNotifyEvent类型的全局事件。这里之所以要用事件进行处理，是因为Synchronize方法本质上是通过消息，将需要同步的过程放到主线程中执行，如果在一些没有消息循环的应用中（如Console或DLL）是无法使用的，所以要使用这个事件进行处理。 }
        if Assigned(WakeMainThread) then
          WakeMainThread(SyncProc.SyncRec.FThread);
        LeaveCriticalSection(ThreadLock);
        // 在执行完WakeMainThread事件后，就退出临界区
        try
          WaitForSingleObject(SyncProc.Signal, INFINITE);
          { 然后调用WaitForSingleObject开始等待在进入临界区前创建的那个Event。这个Event的功能是等待这个同步方法的执行结束，关于这点，在后面分析CheckSynchronize时会再说明。 }
        finally
          EnterCriticalSection(ThreadLock);
        end;
        { 注意在WaitForSingleObject之后又重新进入临界区，但没有做任何事就退出了，似乎没有意义，但这是必须的！
          因为临界区的Enter和Leave必须严格的一一对应。那么是否可以改成这样呢：
          if Assigned(WakeMainThread) then
          WakeMainThread(SyncProc.SyncRec.FThread);
          WaitForSingleObject(SyncProc.Signal, INFINITE);
          finally
          LeaveCriticalSection(ThreadLock);
          end;
          上面的代码和原来的代码最大的区别在于把WaitForSingleObject也纳入临界区的限制中了。看上去没什么影响，还使代码大大简化了，但真的可以吗？事实上是不行！
          因为我们知道，在Enter临界区后，如果别的线程要再进入，则会被挂起。而WaitFor方法则会挂起当前线程，直到等待别的线程SetEvent后才会被唤醒。如果改成上面那样的代码的话，如果那个SetEvent的线程也需要进入临界区的话，死锁（Deadlock）就发生了（关于死锁的理论，请自行参考操作系统原理方面的资料）。死锁是线程同步中最需要注意的方面之一！
        }
      finally
        LeaveCriticalSection(ThreadLock);
      end;
    finally
      CloseHandle(SyncProc.Signal);
    end;
    // 最后释放开始时创建的Event，如果被同步的方法返回异常的话，还会在这里再次抛出异常。
    if Assigned(ASyncRec.FSynchronizeException) then
      raise ASyncRec.FSynchronizeException;
  end;
end;

procedure TApplication.HookSynchronizeWakeup;
begin
    Classes.WakeMianThread:= WakeMainThread;
end;

procedure TApplication.UnhookSynchronizeWakeup;
begin
    Classes.WakeMainThread:= nil;
end;

procedure TApplication.WakeMainThread(Sender: TObject);
begin
    PostMessage(Handle, WM_NULL, 0, 0);
end;

    procedure TApplication.WndProc(var Message: TMessage);
        ...
      begin
        try
		…
     with Message do
         case Msg of
    		 …
        WM_NULL:
        CheckSynchronize;
    …
          except
      HandleException(Self);
         end;
      end; 

function CheckSynchronize(Timeout: Integer = 0): Boolean;
var
  SyncProc: PSyncProc;
  LocalSyncList: TList;
begin
  // 首先，这个方法必须在主线程中被调用（如前面通过消息传递到主线程），否则就抛出异常。
  if GetCurrentThreadID <> MainThreadID then
    raise EThread.CreateResFmt(@SCheckSynchronizeError, [GetCurrentThreadID]);
  { 接下来调用ResetSyncEvent（它与前面SetSyncEvent对应的，之所以不考虑WaitForSyncEvent的情况，是因为只有在Linux版下才会调用带参数的CheckSynchronize，Windows版下都是调用默认参数0的CheckSynchronize）。 }
  if Timeout > 0 then
    WaitForSyncEvent(Timeout)
  else
    ResetSyncEvent;
  { 现在可以看出SyncList的用途了：它是用于记录所有未被执行的同步方法的。因为主线程只有一个，而子线程可能有很多个，当多个子线程同时调用同步方法时，主线程可能一时无法处理，所以需要一个列表来记录它们。 }
  LocalSyncList := nil;
  EnterCriticalSection(ThreadLock);
  try
    Integer(LocalSyncList) := InterlockedExchange(Integer(SyncList),
      Integer(LocalSyncList));
    try
      Result := (LocalSyncList <> nil) and (LocalSyncList.Count > 0);
      if Result then
      begin
        { 在这里用一个局部变量LocalSyncList来交换SyncList，这里用的也是一个原语：InterlockedExchange。同样，这里也是用临界区将对SyncList的访问保护起来。只要LocalSyncList不为空，则通过一个循环来依次处理累积的所有同步方法调用。最后把处理完的LocalSyncList释放掉，退出临界区。 }
        while LocalSyncList.Count > 0 do
        begin
          { 再来看对同步方法的处理：首先是从列表中移出（取出并从列表中删除）第一个同步方法调用数据。然后退出临界区（原因当然也是为了防止死锁）。接着就是真正的调用同步方法了。 }
          SyncProc := LocalSyncList[0];
          LocalSyncList.Delete(0);
          LeaveCriticalSection(ThreadLock);

          try
            try
              SyncProc.SyncRec.FMethod;
            except // 如果同步方法中出现异常，将被捕获后存入同步方法数据记录中。
              SyncProc.SyncRec.FSynchronizeException := AcquireExceptionObject;
            end;

          finally
            EnterCriticalSection(ThreadLock);
            { 重新进入临界区后，调用SetEvent通知调用线程，同步方法执行完成了（详见前面Synchronize中的WaitForSingleObject调用）。 }
          end;
          SetEvent(SyncProc.signal);
        end;
      end;
    finally
      LocalSyncList.Free; // 等list的序列全部执行完后，释放list的资源
    end;
  finally
    LeaveCriticalSection(ThreadLock);
  end;
end;