android - 不使用实时绑定(bind)以编程方式构建 TListView

我有一个包含 TFDMemtable(FireDAC) 的跨平台应用程序。

我的问题是，如何从该表中的记录手动构建 TListView？

我的表格包含按字母顺序排列的男性名字列表。

例如Adam、Anthony、Alan、Brian、Bill、Bob、Ben、Charlie、Craig、Christopher、Colin 等。

我希望 ListView 包含名称分组，例如 A、B、C 等。

到目前为止，我有以下内容:

procedure BuildNameList;
var Litem : TListViewItem;
c : Char;
begin
  ListView1.BeginUpdate;
  try
   ListView1.ClearItems;

  for c := 'A' to 'Z' do
  begin
    with ListView1.Items.Add do
    begin
      Text := char(c);
      Purpose := TListItemPurpose.Header;
    end;

  with dmod.tableNames do
  begin
    First;
   while not Eof do
    begin
      Litem := ListView1.Items.Add;         
      Litem.Text := dmod.tableNames.FieldByName('ForeName').AsString;
      Next;
    end;
  end;
  end;
  finally
    ListView1.EndUpdate;
end;

上面的代码没有给出我想要的结果，发生的事情是我在每个字母组(A-Z)下重复了每个名字。

任何建议/帮助将不胜感激。 谢谢

---

Best Answer-推荐答案

您需要稍微更改您的逻辑以首先添加标题，然后是该标题下的名称，然后是下一个标题和一组名称。这是一个演示的完整测试应用程序。您需要在表单上放置 FMX TListView 和 TClientDataSet 并连接 FormCreate 事件以查看它的工作原理。 (请注意，在 ClientDataSet 上需要索引以确保名称的顺序正确；如果它们没有按字母顺序排列，则代码将无法工作，因为它无法找到需要添加到部分。)

unit Unit3;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.ListView.Types, Data.DB,
  Datasnap.DBClient, FMX.ListView;

type
  TForm3 = class(TForm)
    ListView1: TListView;
    CDS: TClientDataSet;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    procedure BuildNameList;
  public
    { Public declarations }
  end;

var
  Form3: TForm3;

implementation

{$R *.fmx}

procedure TForm3.BuildNameList;
var
  Item: TListViewItem;
  Ch: Char;
begin
  ListView1.BeginUpdate;
  CDS.First;
  try
    ListView1.ClearItems;
    for Ch := 'A' to 'Z' do
    begin
      Item := ListView1.Items.Add;
      Item.Text := Ch;
      Item.Purpose := TListItemPurpose.Header;

      while (CDS.FieldByName('SurName').AsString[1] = Ch) and (not CDS.Eof) do
      begin
        Item := ListView1.Items.Add;
        Item.Text := CDS.FieldByName('SurName').AsString + ', ' +
                     CDS.FieldByName('ForeName').AsString;

        CDS.Next;
      end;
    end;
  finally
    ListView1.EndUpdate;
  end;
end;

procedure TForm3.FormCreate(Sender: TObject);
begin
  // Create some test data
  CDS.FieldDefs.Add('ForeName', ftString, 20);
  CDS.FieldDefs.Add('SurName', ftString, 30);
  CDS.CreateDataSet;
  CDS.Open;
  CDS.AppendRecord(['John', 'Smith']);
  CDS.AppendRecord(['Jane', 'Doe']);
  CDS.AppendRecord(['Ralph', 'Richards']);
  CDS.AppendRecord(['Fred', 'Fredericks']);
  CDS.AppendRecord(['Sam', 'Samuels']);
  CDS.AppendRecord(['Walter', 'Williams']);
  CDS.AppendRecord(['Ann', 'Anderson']);
  CDS.AppendRecord(['Bob', 'Barnes']);

  // Index it to put it in alphabetical order
  CDS.IndexDefs.Add('Names', 'SurName;ForeName', []);
  CDS.IndexName := 'Names';
  BuildNameList;
end;

end.

这是该示例应用的 ListView 中心部分的屏幕截图，您可以查看结果:

关于android - 不使用实时绑定(bind)以编程方式构建 TListView，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/36337997/